dllee

新的筆電(Asus F8Sp)功能很多，但似乎很多都不是很常用到，每次開機都要載入那麼多服務及程式，電腦再快也會覺得慢。我整理了以下的批次檔，可以讓您先將相關的系統服務關閉，等要用時，再執行相關的批次檔，就可以啟用服務，不用時，再執行批次檔，把它們關閉，這樣也可達到省電的目的。

共分四大項：
※ 藍芽啟用 / 藍芽關閉
※ 無線網路啟用 / 無線網路關閉
※ 加密備份啟用 / 加密備份關閉
※ 加密磁碟啟用 / 加密磁碟關閉

主要使用到以下 4 個命令列指令：
NET START　啟動服務
NET STOP　關閉服務
start　啟動應用程式
taskkill　關閉應用程式

批次檔內容如下：

※ 藍芽啟用.bat

@echo off
echo.================================================================
echo.{START} TOSHIBA Bluetooth Services and Applicaitons  {ASUS F8Sp}
echo.----------------------------------------------------------------
echo.2008-09-11   by Dung-Liang Lee (dllee) http://blog.yam.com/dllee
echo.================================================================
echo.start TOSHIBA Bluetooth Service...
NET START "TOSHIBA Bluetooth Service"
IF ERRORLEVEL 2 GOTO step2
IF ERRORLEVEL 1 GOTO sNOTrun

:step2
echo.start Toshiba Bluetooth Manager...
START /D"%ProgramFiles%\Toshiba\Bluetooth Toshiba Stack\" TosBtMng.exe
IF ERRORLEVEL 2 GOTO THEEND
IF ERRORLEVEL 1 GOTO sNOTrun
GOTO THEEND

:sNOTrun
echo.部分服務無法啟動!!         Some service is not start-up!!
echo.您可以再試一次。           You can try again.

:THEEND
pause

※ 藍芽關閉.bat

@echo off
echo.================================================================
echo.{STOP} TOSHIBA Bluetooth Services and Applicaitons   {ASUS F8Sp}
echo.----------------------------------------------------------------
echo.2008-09-11   by Dung-Liang Lee (dllee) http://blog.yam.com/dllee
echo.================================================================
taskkill /F /IM TosBtMng.exe /T
net stop "TOSHIBA Bluetooth Service"

※ 無線網路啟用.bat

@echo off
echo.================================================================
echo.{START} Intel Wireless Services and Applicaitons     {ASUS F8Sp}
echo.----------------------------------------------------------------
echo.2008-09-11   by Dung-Liang Lee (dllee) http://blog.yam.com/dllee
echo.================================================================
echo.start Intel(R) PROSet/Wireless Event Log...
NET START "Intel(R) PROSet/Wireless Event Log"
IF ERRORLEVEL 2 GOTO step2
IF ERRORLEVEL 1 GOTO sNOTrun

:step2
echo.start Intel(R) PROSet/Wireless Registry Service...
NET START "Intel(R) PROSet/Wireless Registry Service"
IF ERRORLEVEL 2 GOTO step3
IF ERRORLEVEL 1 GOTO sNOTrun

:step3
echo.start Intel(R) PROSet/Wireless Service...
NET START "Intel(R) PROSet/Wireless Service"
IF ERRORLEVEL 2 GOTO step4
IF ERRORLEVEL 1 GOTO sNOTrun

:step4
echo.start Intel(R) PROSet/Wireless SSO Service...
NET START "Intel(R) PROSet/Wireless SSO Service"
IF ERRORLEVEL 2 GOTO step5
IF ERRORLEVEL 1 GOTO sNOTrun

:step5
echo.start Wireless Zero Configuration...
NET START "Wireless Zero Configuration"
IF ERRORLEVEL 2 GOTO step6
IF ERRORLEVEL 1 GOTO sNOTrun

:step6
echo.start ZeroCfgSvc MFC Application...
START /D"%ProgramFiles%\Intel\Wireless\Bin\" ZCfgSvc.exe
IF ERRORLEVEL 2 GOTO step7
IF ERRORLEVEL 1 GOTO sNOTrun

:step7
echo.start Intel Framework MFC Application...
START /D"%ProgramFiles%\Intel\Wireless\Bin\" iFrmewrk.exe
START /D"%ProgramFiles%\Intel\Wireless\Bin\" Dot1XCfg.exe -Embedding
IF ERRORLEVEL 2 GOTO THEEND
IF ERRORLEVEL 1 GOTO sNOTrun
GOTO THEEND

:sNOTrun
echo.部分服務無法啟動!!         Some service is not start-up!!
echo.您可以再試一次。           You can try again.

:THEEND
pause

※ 無線網路關閉.bat

@echo off
echo.================================================================
echo.{STOP} Intel Wireless Services and Applicaitons      {ASUS F8Sp}
echo.----------------------------------------------------------------
echo.2008-09-11   by Dung-Liang Lee (dllee) http://blog.yam.com/dllee
echo.================================================================
taskkill /F /IM iFrmewrk.exe
taskkill /F /IM ZCfgSvc.exe
taskkill /F /IM Dot1XCfg.exe
net stop "Intel(R) PROSet/Wireless SSO Service"
net stop "Intel(R) PROSet/Wireless Service"
net stop "Intel(R) PROSet/Wireless Registry Service"
net stop "Intel(R) PROSet/Wireless Event Log"
taskkill /F /IM EvtEng.exe >nul
net stop "Wireless Zero Configuration"

※ 加密備份啟用.bat

@echo off
echo.================================================================
echo.{START} ASUS Data Security Manager                   {ASUS F8Sp}
echo.----------------------------------------------------------------
echo.2008-09-12   by Dung-Liang Lee (dllee) http://blog.yam.com/dllee
echo.================================================================
echo.start ADSM(ASUS Data Security Manager) Service...
NET START "ADSM Service"
IF ERRORLEVEL 2 GOTO step2
IF ERRORLEVEL 1 GOTO sNOTrun

:step2
echo.start ATKGFNEX Service...
NET START "ATKGFNEX Service"
IF ERRORLEVEL 2 GOTO THEEND
IF ERRORLEVEL 1 GOTO sNOTrun

:sNOTrun
echo.部分服務無法啟動!!         Some service is not start-up!!
echo.您可以再試一次。           You can try again.

:THEEND
pause

※ 加密備份關閉.bat

@echo off
echo.================================================================
echo.{STOP} ASUS Data Security Manager                    {ASUS F8Sp}
echo.----------------------------------------------------------------
echo.2008-09-12   by Dung-Liang Lee (dllee) http://blog.yam.com/dllee
echo.================================================================
net stop "ATKGFNEX Service"
net stop "ADSM Service"

※ 加密磁碟啟用.bat

@echo off
echo.================================================================
echo.{START} Trusted Platform Services and Applicaitons   {ASUS F8Sp}
echo.----------------------------------------------------------------
echo.2008-09-11   by Dung-Liang Lee (dllee) http://blog.yam.com/dllee
echo.================================================================
echo.start Trusted Platform Core Service...
NET START "Trusted Platform Core Service"
IF ERRORLEVEL 2 GOTO step2
IF ERRORLEVEL 1 GOTO sNOTrun

:step2
echo.start Security Platform Management Service...
NET START "Security Platform Management Service"
IF ERRORLEVEL 2 GOTO step3
IF ERRORLEVEL 1 GOTO sNOTrun

:step3
echo.start Personal Secure Drive 服務...
NET START "Personal Secure Drive 服務"
IF ERRORLEVEL 2 GOTO step4
IF ERRORLEVEL 1 GOTO sNOTrun

:step4
echo.start PSD Runtime Application...
START /D"%ProgramFiles%\Infineon\Security Platform Software\" PSDrt.exe
IF ERRORLEVEL 2 GOTO step7
IF ERRORLEVEL 1 GOTO sNOTrun

:step7
echo.start Taskbar Notification Icon...
START /D"%ProgramFiles%\Infineon\Security Platform Software\" SpTna.exe
IF ERRORLEVEL 2 GOTO THEEND
IF ERRORLEVEL 1 GOTO sNOTrun
GOTO THEEND

:sNOTrun
echo.部分服務無法啟動!!         Some service is not start-up!!
echo.您可以再試一次。           You can try again.

:THEEND
pause

※ 加密磁碟關閉.bat

@echo off
echo.================================================================
echo.{STOP}  Trusted Platform Services and Applicaitons   {ASUS F8Sp}
echo.----------------------------------------------------------------
echo.2008-09-11   by Dung-Liang Lee (dllee) http://blog.yam.com/dllee
echo.================================================================
taskkill /F /IM SpTna.exe
taskkill /F /IM PSDrt.exe
net stop "Personal Secure Drive 服務"
net stop "Security Platform Management Service"
net stop "Trusted Platform Core Service"

您可以先將以上所有 net start/stop 所指定的服務全部設定為「手動」啟動，這樣下次重開機時，它們就不會自動啟動了。此外，記得使用之前介紹過的 AutoRun 工具，將以上 start/taskkill 的應用程式，取消他們開機自動執行。

完成以上修改，重開機後，再打開工作管理員，總算可以「一頁了然」

附件是以上所有批次檔的 ZIP，解壓後即可使用
附件：AsusF8Sp.dllee.bat.zip